;hsqcbietgpjcsp.2
;avance-version (11/08/10)
;HSQC
;2D H-1/X correlation via double inept transfer
;for determination of 1J CH via splitting in F1
;phase sensitive using Echo/Antiecho-TPPI gradient selection
;with decoupling during acquisition
;using trim pulses in inept transfer
;using shaped pulses for inversion and refocussing on f2 - channel
;using G_BIRD(r) to remove long range couplings in t1
;with J scaling in t1
;
;(J. Furrer, M. John, H. Kessler & B. Luy
;   J. Biomol. NMR. 37, 231-243 (2007))
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
#include <De.incl>


"p2=p1*2"
"d2=1s/(cnst2*2)"
"d4=1s/(cnst2*4)"
"d11=30m" 

"p29=300u"


"d0=3u"
"d20=3u"

"in0=inf1/2"

"in20=in0*cnst16"


"d62=aq/l0"
"d63=d62/2"


"l1=l0-1"


"DELTA=p16+d16+d0*2+p2-p3*4/PI"
"DELTA1=d4-p16-d16-larger(p2,p14)/2-de-8u"
"DELTA2=d4-larger(p2,p14)/2"
"DELTA3=d2-p16-d16-larger(p2,p39)/2"
"DELTA4=d4-larger(p2,p14)/2-p1*2/PI" 
"DELTA5=d2-larger(p2,p14)/2"

"TAU=p39"


"acqt0=0"
baseopt_echo


1 ze
  d11 pl12:f2
2 d11 do:f2
  4u BLKGRAD
  d1 pl1:f1
  50u UNBLKGRAD 
3 (p1 ph1)
  DELTA2
  4u
  (center (p2 ph1) (p14:sp3 ph6):f2 )
  4u
  DELTA2 pl2:f2
  p28 ph1
  4u
  (p1 ph8)
  
  (p3 ph3):f2
  d20 
  (p1 ph1)
  p16:gp3
  d16
  DELTA3
  (center (p2 ph1) (p39:sp4 ph1):f2 )
  DELTA3
  p16:gp3
  d16
  (p1 ph1)
  d20 
  d0
  (p2 ph1)
  d0
  p16:gp1*EA
  d16
  (p39:sp4 ph4):f2
  DELTA pl2:f2
  (p3 ph4):f2

  (p1 ph1)
  DELTA4
  (center (p2 ph1) (p14:sp3 ph1):f2 )
  4u
  p16:gp2
  d16
  DELTA1 pl12:f2
  4u 
  4u cpd2:f2
  ACQ_START(ph30,ph31)
  0.1u START_NEXT_SCAN
  
  0.1u REC_UNBLK
  0.05u DWELL_RELEASE
  d63
  0.05u DWELL_HOLD
  0.1u REC_BLK

  10u do:f2
  p29:gp4
  d16
  TAU
  (p1 ph1)
  DELTA5
  4u
  (center (p2 ph2) (p39:sp4 ph1):f2 )
  4u
  DELTA5
  (p1 ph7)
  (p39:sp4 ph1):f2
  p29:gp4
  d16 pl12:f2
  20u
  p29:gp5
  d16
  4u
  (p2 ph1)
  4u
  p29:gp5
  d16
  10u cpd2:f2

4 0.1u REC_UNBLK
  0.05u DWELL_RELEASE
  d62
  0.05u DWELL_HOLD
  0.1u REC_BLK

  10u do:f2
  p29:gp4
  d16
  TAU
  (p1 ph1)
  DELTA5
  4u
  (center (p2 ph2) (p39:sp4 ph1):f2 )
  4u
  DELTA5
  (p1 ph7)
  (p39:sp4 ph1):f2
  p29:gp4
  d16 pl12:f2
  20u
  p29:gp5
  d16
  4u
  (p2 ph1)
  4u
  p29:gp5
  d16
  10u cpd2:f2

  lo to 4 times l1

  0.1u REC_UNBLK
  0.05u DWELL_RELEASE
  d62*2
  0.05u DWELL_HOLD
  0.1u REC_BLK

  rcyc=2

  d11 do:f2 mc #0 to 2 
     F1EA(calgrad(EA), caldel(d0, +in0) & caldel(d20, +in20) & calph(ph3, +180) & calph(ph6, +180) & calph(ph31, +180))

4u BLKGRAD
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 0 0 2 2 2 2
ph6=0
ph7=2
ph8=1 1 3 3
ph30=0
ph31=0 2 2 0 2 0 0 2


;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;sp3: f2 channel - shaped pulse 180 degree
;sp4: f2 channel - shaped pulse (180degree refocussing)
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p14: f2 channel - 180 degree shaped pulse for inversion
;p16: homospoil/gradient pulse
;p28: f1 channel - trim pulse
;p39: f2 channel - 180 degree shaped pulse for refocussing
;                      Bip720,100,10.1 (160us at 600.13 MHz)
;d0 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d2 : 1/(2J)XH
;d4 : 1/(4J)XH
;d11: delay for disk I/O                             [30 msec]
;d16: delay for homospoil/gradient recovery
;d2 : incremented delay (2D)                         [3 usec]
;cnst2: = J(XH)
;cnst16: = J(scale) factor
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;in20: = in0*cnst16
;NS: 1 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho
;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence


;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1% for C-13
;gpz3: 11%
;gpz4: 3%
;gpz5: 5%

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.50



;$Id: hsqcbietgpjcsp.2,v 1.1.2.2 2011/09/09 10:45:25 ber Exp $
